ZÄHLENWENN-Funktion in Excel

Wer Excel nur verwendet, um per Hand Tabellen zu erstellen, verkennt den Nutzen, den das Microsoft-Werkzeug hat. Mit vielen nützlichen Funktionen können Sie sich Ihre Arbeit erleichtern – sowohl im privaten Umfeld als auch bei der Arbeit. Damit man aber von den Vorteilen der Tabellenkalkulation profitieren kann, muss man die einzelnen hilfreichen Funktionen erst einmal verstehen. Um ein solches nützliches Hilfsmittel handelt es sich auch bei der ZÄHLENWENN-Funktion (oder auf Englisch COUNTIF). Erfahren Sie, wofür man die Funktion benötigt und wie man diese korrekt einsetzt.

Wofür braucht man ZÄHLENWENN?

Stellen Sie sich vor, Sie haben eine unsortierte Liste mit Einträgen. Darin könnten z. B. Verkäufe der letzten Monate aufgelistet sein. Nun möchten Sie herausfinden, wie häufig ein bestimmter Artikel verkauft wurde. Statt per Hand die komplette Liste zu durchforsten, nutzen Sie in einem solchen Fall die ZÄHLENWENN-Funktion. Sie zählen also, wenn ein bestimmter Wert zutrifft.

In Excel ist ZÄHLENWENN eine statistische Funktion. Wie am Anwendungsbeispiel zu erkennen, nutzt man die Funktion, um eine Statistik zu erstellen. Wenn Sie die Frage „Wie häufig wurde Artikel XY verkauft?“ nun auf jedes verfügbare Produkt übertragen, können Sie etwa herausfinden, welcher Artikel am beliebtesten ist. Mit den statistischen Daten lassen sich anschließend z. B. Diagramme erstellen.

Bei der ZÄHLENWENN-Funktion handelt es sich im Prinzip um eine Kombination aus der WENN-Funktion (eine logische Funktion) und der ANZAHL-Funktion bzw. der ANZAHL2-Funktion (statistische Funktionen). Die Kombination ergibt, dass Excel eine Zelle nur dann zählt, wenn ein bestimmter Wert erfüllt ist.

Nicht zu verwechseln ist ZÄHLENWENN mit SUMMEWENN: Die ähnliche Funktion gibt nicht die Anzahl der Werte innerhalb eines Datenbereichs wieder, sondern summiert direkt bestimmte Mengen. In unserem Beispiel: Der entsprechende Artikel wurde jeweils pro Verkaufsaktion in größeren Mengen verkauft. SUMMEWENN ermittelt, wie viele einzelne Produkte schließlich veräußert wurden.

Wie geht es richtig? ZÄHLENWENN im Einsatz

Bei Excel-Funktionen ist es wichtig, die richtige Syntax einzuhalten:

                =ZÄHLENWENN(Bereich;Suchkriterium)

Mit dem Begriff Bereich sind die Zellen in Ihrer Tabelle gemeint, in denen die zu zählenden Angaben stehen. Das Suchkriterium gibt den entsprechenden Wert an, der berücksichtigt werden soll. Den Bereich geben Sie mit einem Start- und einem Endpunkt an, zwischen beiden steht ein Doppelpunkt. Die Angabe „B3:B14“ umfasst also sowohl die beiden genannten Zellen als auch alle, die innerhalb der Spalte dazwischen liegen. Alternativ gibt Ihnen Excel die Möglichkeit, Bereiche mit der Maus zu ziehen. Die entsprechenden Zellenbereiche werden dann farbig markiert. Es ist auch möglich, die komplette Spalte zu markieren. Hierbei gibt man als Werte nur die Spalte und keine Zeilen an: „B:B“. Analog funktioniert dies natürlich auch mit Zeilen.

Das Suchkriterium können Sie entweder als Wert angeben, den Sie dann in Anführungszeichen setzen (z. B. „Schuhe“), oder indem Sie auf eine Zelle verweisen, in der dieser Wert steht (z. B. B3). Beide Angaben (Bereich und Suchkriterium) trennt man durch ein Semikolon voneinander. Es kommen keine Leerzeichen in der Syntax vor.

                =ZÄHLENWENN(B3:B14;"Schuhe")

                =ZÄHLENWENN(B3:B14;F3)

Hinweis

Funktionen werden in Excel immer mit einem Gleichheitszeichen eingeleitet. Ansonsten interpretiert das Programm die Angabe als einfache Zeichenfolge und schreibt diese sichtbar in die Zelle.

Excel bietet auch hilfreiche Autovervollständigungen an. Ziehen Sie dazu die Funktion (am unteren rechten Rand der aktivierten, also angeklickten Zelle) eine Zeile weiter: Die angegebenen Zellen unter Bereich und Suchkriterium passen sich automatisch an. Die Funktion bezieht nun auch automatisch auf Zellen, die eine Zeile tiefer liegen. Wenn Sie das nicht möchten, etwa weil der Suchbereich der gleiche bleiben soll, können Sie diese Angaben als absolute Werte eintragen. Dafür fügen Sie Dollarzeichen ein:

                =ZÄHLENWENN($B$3:$B$14;F3)

ZÄHLENWENN hat auch noch eine erweiterte Funktion namens ZÄHLENWENNS. Damit fügen Sie mehrere Bereiche und so auch mehrere Suchkriterien in Ihre Funktion ein. Sie können z. B. nur solche Schuhverkäufe zählen, die mehr als ein Produkt beinhalten:

=ZÄHLENWENNS(B3:B14;$G4;C3:C14;>1)

Hinweis

Die ZÄHLENWENN-Funktion achtet nicht auf Groß- und Kleinschreibung.

Die ZÄHLENWENN-Funktion anhand von Beispielen erklärt

Nehmen wir an, Sie besitzen ein Ladengeschäft und für Ihre Statistik möchten Sie herausfinden, wie viele Käufer aus Ihrem direkten Umfeld kommen. Dafür haben Sie alle Kunden gefragt, ob Sie bereit wären, Ihnen ihre Postleitzahl zu nennen. Alle Angaben tragen Sie nacheinander in eine Tabelle ein. Nun können Sie beispielsweise Zellen zählen, wenn sich in diesen Ihre eigene Postleitzahl befindet.

 

                =ZÄHLENWENN(B3:B17;"10969")

Tipp

In diesem Beispiel verwenden wir Zahlen als Text. Für die ZÄHLENWENN-Funktion macht das im Prinzip keinen Unterschied, aber damit Ihnen in anderen Situationen keine Probleme entstehen, sollten Sie die Zellen auch als Text formatieren.

So bekommen Sie heraus, wie viele Kunden direkt um Ihr Ladengeschäft herum wohnen. Wenn Sie nun auch noch das Gegenteil wissen möchten, also wer alles aus einem anderen Postleitzahlgebiet kommt, müssen Sie vor das Suchkriterium ein Kleiner-als-Zeichen (<) und ein Größer-als-Zeichen (>) setzen.

                =ZÄHLENWENN(B3:B17;"<>10969")

Wenn Sie den Wert nicht direkt in die Funktion eintragen und stattdessen auf den Wert in einer bestimmten Zelle referieren möchten, müssen Sie die Negation („<>“) mit dem Verkettungsoperator (&) mit der Zelle verknüpfen:

                =ZÄHLENWENN(B3:B17;"<>"&B3)

Darüber hinaus haben Sie die Kunden auch nach dem Alter befragt und diese Zahlen zugeordnet zu den jeweiligen Postleitzahlen in eine Spalte eingetragen. Sie gehen davon aus, dass Ihr Angebot vor allem Menschen über 50 anspricht. Um diese Vermutung zu verifizieren, können Sie die ZÄHLENWENN-Funktion einsetzen. Da Sie nicht nur alle Käufer über 50, sondern auch jene, die genau 50 sind, erfassen wollen, muss die Funktion Größer-als und Gleich enthalten:

                =ZÄHLENWENN(C3:C17; ">=50")

Hierbei interessiert Sie natürlich ebenso das negative Ergebnis, also wie viele Menschen jünger als 50 Jahre sind. Dafür benötigen Sie in diesem Fall keine Negation: Das Kleiner-als-Zeichen genügt vollkommen:

                =ZÄHLENWENN(C3:C17; "<50")

Sollte jemand Ihnen keine Angabe zum Alter gegeben haben, wird dieser Wert einfach herausgerechnet. Sie werden feststellen, dass das einfache Entfernen einer Postleitzahl, die nicht 10969 ist, keine Auswirkungen auf das Ergebnis hat. Hierfür können Sie Ihre Formel erweitern, indem Sie zusätzlich alle Zellen zählen, die leer sind, und die Anzahl vom ersten Ergebnis subtrahieren. Um Excel mitzuteilen, dass Sie leere Zellen als Suchkriterium verwenden möchten, lassen Sie den Bereich zwischen den beiden Anführungszeichen einfach frei – schreiben die beiden Zeichen also direkt nacheinander:

                =ZÄHLENWENN(B3:B17;"<>10969")-ZÄHLENWENN(B3:B17;"")

Alternativ können Sie an dieser Stelle die erweiterte Funktion ZÄHLENWENNS verwenden. Hierfür fügen Sie Ihrer ursprünglichen Formel ein weiteres Suchkriterium hinzu, nämlich dass leere Zellen nicht hinzugerechnet werden sollen. Sie subtrahieren also nicht alle leeren Zellen, sondern schließen beim Zählen alle leere Zellen aus:

                =ZÄHLENWENNS(B3:B17;"<>10969";B3:B17;"<>")

Wenn Sie jetzt schließlich noch – aus welchem Grund auch immer – herausfinden möchten, wie viele der Kunden über 50 aus Ihrem Postleitzahlbereich kommen, können Sie ebenfalls die ZÄHLENWENNS-Funktion verwenden. Dafür fügen Sie das zusätzliche Kriterium in die Formel ein:

                =ZÄHLENWENNS(B3:B17;"10969";B3:B17;"<>";C3:C17;">=50")

Hinweis

Excel hat bei ZÄHLENWENN ein Problem mit langen Zeichenfolgen. Um Suchkriterien mit mehr als 255 Zeichen zu verwenden, können Sie mehrere Kriterien miteinander verketten. Dafür verwenden Sie den Verkettungsoperator „&“:

=ZÄHLENWENN(B3:B17;"109"&"69").

Bei Ihrer Befragung haben Sie zusätzlich noch notiert, was die Kunden jeweils gekauft haben. Als Besitzer eines Schuhgeschäfts interessieren Sie sich dafür, wie häufig bestimmte Schuhe verkauft wurden, und möchten also nur diese Verkäufe berücksichtigen. Hierfür können Sie einen Platzhalter einsetzen, der in Excel mit einem Asterisken (*) realisiert wird:

                =ZÄHLENWENN(D3:D17;"*schuhe")

Hinweis

Platzhalter funktionieren nur für Texteingaben. Zahlenwerte lassen sich hiermit nicht ersetzen. Das gleiche gilt für das Fragezeichen (?) als Platzhalter: Hiermit können Sie jeweils ein Zeichen ersetzen. Möchten Sie stattdessen tatsächlich nach einem Fragezeichen oder einem Sternchen suchen, stellen Sie zur Maskierung des Zeichens eine Tilde (~) voran.