Wenn-Dann in Excel: So funktioniert die WENN-Funktion

Sie ist eine der beliebtesten Funktionen in Excel: WENN. Manchmal soll in der Tabellenkalkulation erst dann etwas ausgeführt werden, wenn ein bestimmter Zustand eintrifft. Was man beim Programmieren als If-Anfrage kennt, lässt sich in Excel mit einer Wenn-Dann-Funktion lösen. Das Prinzip ist das gleiche: Wenn ein Wert wahr ist, dann mach das eine, sonst mach das andere. Wir erklären Ihnen, wie die Wenn-Dann-Funktion richtig eingesetzt wird und wofür man Sie braucht.

Was ist die Wenn-Dann-Funktion?

Mit der WENN-Funktion (so heißt die Formel korrekt) können Sie einen logischen Vergleich anstellen: Ist der abgefragte Wert mit dem erwarteten identisch oder nicht? Nur wenn diese Abfrage wahr ist, soll ein bestimmter Fall eintreten. Ist der Vergleich falsch, löst dies eine andere Aktion aus – also: wenn A, dann B, sonst C.

Damit gehört Wenn-Dann in Excel zu den wichtigsten Hilfsmitteln. Die Funktion kann in allen möglichen Situationen zum Einsatz kommen: Egal, ob Sie mit einem einfachen Mitgliederverzeichnis, einem Tabellenblatt zu Unternehmenskennzahlen oder statistischen Auswertungen arbeiten – WENN wird Ihnen allein oder in Kombination mit anderen Funktionen eine große Hilfe sein.

Wie funktioniert die Wenn-Dann-Funktion?

Jeder Funktion in Excel liegt eine bestimmte Syntax zugrunde, so auch WENN:

=WENN(Prüfung;Dann_Wert;Sonst_Wert)

Die Funktion beinhaltet demnach drei Parameter, wovon Sie die ersten beiden verpflichtend ausfüllen müssen.

  • Prüfung: An dieser Stelle muss eine Bedingung stehen, ein Vergleich zwischen zwei Werten, wobei einer oder beide in Form von Referenzen auf Zellen vorliegen können. Mögliche Bedingungen lauten:
    • Gleich (=)
    • Ungleich (<>)
    • Kleiner als (<)
    • Größer als (>)
    • Kleiner als oder gleich (<=)
    • Größer als oder gleich (>=)
  • Dann_Wert: In diesen Parameter tragen Sie ein, was passieren soll, wenn die abgeprüfte Bedingung wahr ist. Als Ergebnisse können Werte, Zeichenketten, Zellbezüge oder auch andere Funktionen dienen. Sie müssen Zeichenketten in Anführungszeichen setzen.
  • Sonst_Wert: Der letzte Parameter ist optional. Wenn Sie an dieser Stelle nichts angeben, wird die Funktion FALSCH ausgeben. Ansonsten verhält sich Sonst_Wert analog zum Dann_Wert.

In der Praxis könnte eine Wenn-Dann-Funktion in Excel also so aussehen:

=WENN(A1>=100;"Ziel erreicht";"Ziel noch nicht erreicht")

Tipp

In Excel werden Funktionen in der Bearbeitungszeile immer mit einem Gleichheitszeichen eingeleitet und Parameter in eine Klammer eingebettet. Wenn Sie Zellbezüge verwenden, können Sie diese mit einem Dollarzeichen absolut machen. Das bedeutet, dass Funktionen auch beim Kopieren in andere Zellen den Bezug auf die ursprüngliche Zelle behalten.

Wenn Sie möchten, müssen Sie die WENN-Funktion auch nicht per Hand in die Bearbeitungszeile eintragen. Mit „Funktion einfügen“ bietet Ihnen Excel eine Hilfe beim korrekten Ausfüllen von Formeln.

Wenn-Dann an einem Beispiel erklärt

Die WENN-Funktion findet in den verschiedensten Situationen Anwendung. Die logische Abfrage kann z. B. zum Sortieren von Datenpunkten verwendet werden. Beim folgenden Beispiel handelt es sich um ein Inventar. Mit WENN lässt sich nun etwa eine Markierung erstellen, sobald ein bestimmter Mindestbestand unterschritten wird.

=WENN(D2<10;"Ja";"Nein")

Hinweis

Da Sie den Zellbezug in der Funktion nicht absolut setzen, können Sie die Formel durch Ziehen des Ausfüllkästchens in weitere Zeilen kopieren. Die Bezüge werden dabei automatisch angepasst.

Neben einem Zellbezug ist es aber auch möglich, weitere Funktionen in WENN unterzubringen. So kann man dem ursprünglichen Preis einen Rabatt zuordnen, falls der letzte Abverkauf schon zu lange her ist.

=WENN((TAGE(HEUTE();F2))>30;C2*0,75;C2)

In diesem Fall ist die TAGE-Funktion Teil der Prüfung: Das aktuelle Datum wird mit dem angegebenen (in F2) verglichen und die Differenz in der Anzahl der Tage ausgegeben. WENN überprüft, ob die Anzahl größer ist als 30. Ist dies der Fall, tritt der Dann_Wert ein, in dem Sie eine mathematische Berechnung untergebracht haben: Auf den ursprünglichen Wert (in Zelle F2) wird ein Rabatt gegeben. Ansonsten bleibt der Originalwert erhalten.

Sie können Excel-Funktionen aber natürlich auch in den Parametern für Dann und Sonst unterbringen. Sehr beliebt ist z. B. die Verschachtelung von Wenn-Dann in Excel. Der Nachteil von WENN liegt darin, dass die Prüfung nur zwei Ergebnisse kennt: WAHR oder FALSCH. Wenn man aber mehrere Zustände unterscheiden möchte, kann anstelle von Sonst_Wert erneut eine WENN-Funktion auftreten, die eine weitere Überprüfung durchführt.

In unserem Beispiel wäre es denkbar, bereits vergünstigen Produkten einen noch höheren Rabatt zu gewähren, wenn von diesen nur noch wenige Exemplare vorhanden sind. Damit haben wir zwei Bedingungen: Der letzte Abverkauf ist schon über 30 Tage her und es befinden sich nicht mehr als 10 Exemplare im Lager. Deshalb müssen wir zum einen eine UND-Verknüpfung im Prüfparameter unterbringen und zum anderen eine weitere Wenn-Dann-Abfrage im Sonst-Parameter, denn wir möchten drei Ergebnisse möglich machen: 50 % Rabatt, 25 % Rabatt und kein Rabatt.

=WENN(UND(TAGE(HEUTE();F2)>30;E2<10);C2*0,5;WENN(TAGE(HEUTE();F2);C2*0,75;C2))

Hinweis

Die Verschachtelung der WENN-Funktion ist sehr praktisch, hat aber ihre Grenzen: Theoretisch kann Excel Wenn-Dann 64-mal innerhalb einer Formel bearbeiten. Davon ist aber abzuraten. Die Verschachtelungen führen zu einer Komplexität, bei der es schwer wird, eine fehlerfreie Syntax zu erstellen. Beispielsweise kann es schnell passieren, dass man eine oder mehrere Klammern vergisst. In so langen Formeln ist auch die Fehlersuche sehr aufwendig. U. U. ist es daher sinnvoll, mit Hilfsspalten oder anderen Funktionen wie dem SVERWEIS zu arbeiten. Eine andere Lösung für das Problem der Verschachtelungen kann die WENNS-Funktion sein.

Natürlich ist es auch möglich, Wenn-Dann in andere Excel-Funktionen einzubauen. Denkbar ist dies z. B. in einer einfachen SUMME-Funktion. Stellen wir uns vor, das Beispiel-Unternehmen möchte erfahren, wie viele Posten derzeit von einem Rabatt erfasst werden. In einer solchen Situation kann man beispielsweise diese Formel anwenden:

=SUMME(WENN(D2=C2;0;1);WENN(D3=C3;0;1);….)

In der Praxis wird das aber eine sehr lange Formel. Arbeiten Sie lieber mit einer Hilfspalte, in der Sie wiederum die einfache Wenn-Dann-Funktion anwenden, und setzen Sie dann die ZÄHLENWENN-Funktion ein. Damit können Sie nur solche Zellen zählen, die einem bestimmten Kriterium entsprechen, also z. B. das Wort „Ja“ enthalten:

=ZÄHLENWENN(E2:E11;"Ja")

WENNS: Erweiterung von Wenn-Dann

Seit Office 2016 bietet Excel Ihnen noch eine andere Wenn-Dann-Funktion. Die WENNS-Funktion arbeitet ähnlich wie WENN: Einer logischen Prüfung wird ein Dann_Wert zugeordnet – allerdings bis zu 127-mal. Die Syntax lautet demnach:

=WENNS(Etwas ist Wahr1; Wert wenn Wahr1; [Etwas ist Wahr2; Wert wenn Wahr2];…[Etwas ist Wahr127; Wert wenn Wahr127])

Was dabei auffällt: Es gibt keinen Sonst_Wert mehr. Das bedeutet aber auch, dass man den Umkehrschluss – also in unserem Beispiel den Fall, dass keine Rabatte zum Einsatz kommen – selbst definieren muss. Daher gilt:

=WENNS(UND(TAGE(HEUTE();F2)>30;E2<10);C2*0,5;TAGE(HEUTE();F2)>30;C2*0,75;TAGE(HEUTE();F2)<=30;C2)

Die beiden Prüfungen für die Rabatte kommen jeweils hintereinander. Anschließend folgt der Sonst-Fall: Alle Produkte, deren letzter Verkauf weniger oder gleich 30 Tage her ist.


Auf dem Laufenden bleiben?

Jetzt zu unserem Newsletter anmelden und
gratis Online-Marketing Whitepaper
sichern.